hk.pkl

// Хуки ставит `hk install`: на git 2.54+ это записи hook.* в .git/config,
// общий core.hooksPath дерева кита они не трогают.
amends "package://github.com/jdx/hk/releases/download/v2.8.1/hk@2.8.1#/Config.pkl"
import "package://github.com/jdx/hk/releases/download/v2.8.1/hk@2.8.1#/Builtins.pkl"

// Быстрые проверки идут на каждый коммит. Сеть и долгие шаги вынесены в all:
// их гоняют check, pre-push и CI.
local fast = new Mapping<String, Step> {
  ["format"] {
    glob = List("**/*.ts", "**/*.tsx", "**/*.js", "**/*.jsx", "**/*.mjs", "**/*.cjs")
    check = "pnpm exec oxfmt --check --no-error-on-unmatched-pattern {{files}}"
    fix = "pnpm exec oxfmt --no-error-on-unmatched-pattern {{files}}"
  }
  ["lint"] {
    glob = List("**/*.ts", "**/*.tsx", "**/*.js", "**/*.jsx", "**/*.mjs", "**/*.cjs")
    check = "pnpm exec oxlint {{files}}"
  }
  ["tflint"] {
    glob = List("**/*.tf")
    check = "tflint --recursive --config \"$(pwd)/.tflint.hcl\""
  }
  ["hadolint"] {
    glob = List("**/Dockerfile*")
    check = "hadolint {{files}}"
  }
  ["shellcheck"] {
    glob = List("**/*.sh")
    check = "shellcheck {{files}}"
  }
  ["rumdl"] = Builtins.rumdl
  ["typos"] = Builtins.typos
  ["jactionlint"] = Builtins.jactionlint
}

local all = (fast) {
  ["lychee"] {
    glob = List("**/*.md")
    check = "lychee --config lychee.toml --no-progress {{files}}"
  }
}

hooks {
  // stash выключен: на время хука он откатывает непроиндексированные файлы
  // рабочего дерева, в том числе чужие правки параллельной сессии.
  ["pre-commit"] {
    fix = true
    stash = "none"
    steps = fast
  }
  // История читается release-please, а коммиты идут прямо в main, поэтому
  // заголовок проверяется до записи. В CI тот же commitlint гоняется по
  // диапазону пуша.
  ["commit-msg"] {
    steps {
      ["commitlint"] {
        check = "commitlint --edit {{commit_msg_file}}"
      }
    }
  }
  ["pre-push"] {
    steps = all
  }
  ["check"] { steps = all }
  ["fix"] {
    fix = true
    steps = all
  }
}