jit-lock-refontify when called on folded text causes misalignment

[akashpal-21]

Suppose the org file starts with org-startup-folded != 'showeverything, and valign-mode is called as part of an org-mode-hook

Then,

(if valign-mode
        (progn
          (add-hook 'jit-lock-functions #'valign-region 98 t)
         ... [code block]
          (jit-lock-refontify))

This causes tables that are currently under invisible headlines to be crooked. User has to press TAB on the table to align again manually.

Currently doing the following as a temporary solution

(with-eval-after-load 'valign
  (defun valign-org-cycle-refontification (state)
    "Refontify only the visible part affected by `org-cycle`.
STATE is a symbol indicating the new visibility state."
    (when (bound-and-true-p valign-mode)
      (cond
       ;; Expand direct children: Only refontify from current headline to its children
       ((eq state 'children)
	(let ((start (point))
              (end (save-excursion (outline-next-heading) (point))))
	  (jit-lock-refontify start end)))
       
       ;; Expand full subtree: Refontify from headline to subtree end
       ((eq state 'subtree)
	(let ((start (point))
              (end (save-excursion (org-end-of-subtree t t))))
	  (jit-lock-refontify start end)))
       
       ;; Fully expanded: Refontify everything
       ((eq state 'all)
	(jit-lock-refontify (point-min) (point-max))))))

  (defun valign--refontification-advice ()
    (if valign-mode
	(add-hook 'org-cycle-hook #'valign-org-cycle-refontification 98 'local)
      (remove-hook 'org-cycle-hook #'valign-org-cycle-refontification 'local)))
  (add-hook 'valign-mode-hook #'valign--refontification-advice))

probably not the most efficient or elegant way to solve it, but it works for me currently. Please let me know if any elegant other solution exists.

org-fold-core-style = overlays)

[casouri]

After thinking a bit about it, I actually think your solution is right! If we can't properly align the tables when it's hidden, then all that we can do is refontify it when it appears. jit-lock-refontify is actually very cheap to call, it merely marks the region as "unfontified", and redisplay will fontify the parts that are visible on-demand.

If you make a PR I'll gladly merge it.

[akashpal-21]

@casouri I apologise, I forgot to reply in time; I don't know how to do PR, I can give you the minimal diff - and if you are satisfied, can you push from your side?

diff -u /home/akash/projects/valign/valign-old.el /home/akash/projects/valign/valign.el
--- /home/akash/projects/valign/valign-old.el	2025-12-21 14:06:25.062446810 +0530
+++ /home/akash/projects/valign/valign.el	2025-12-21 14:05:10.818437310 +0530
@@ -1078,6 +1078,19 @@
              (valign--align-p))
     (valign-table)))
 
+(defun valign--org-cycle-re (state)
+  "Refontify only the visible part affected by `org-cycle`.
+STATE is a symbol indicating the new visibility state."
+  (when (bound-and-true-p valign-mode)
+    (pcase state
+      ('children (let ((start (point))
+		       (end (save-excursion (outline-next-heading) (point))))
+		   (jit-lock-refontify start end)))
+      ('subtree (let ((start (point))
+		      (end (save-excursion (org-end-of-subtree t t))))
+		  (jit-lock-refontify start end)))
+      ('all (jit-lock-refontify (point-min) (point-max))))))
+
 (defun valign-reset-buffer ()
   "Remove alignment in the buffer."
   (with-silent-modifications
@@ -1141,6 +1154,8 @@
                         org-table-blank-field
                         markdown-cycle))
             (advice-add fn :after #'valign--tab-advice))
+	  ;; ref: issue#36
+	  (add-hook 'org-cycle-hook #'valign--org-cycle-re 98 t)
           (dolist (fn '(text-scale-increase
                         text-scale-decrease
                         org-toggle-inline-images))
@@ -1156,6 +1171,7 @@
           (jit-lock-refontify))
       (remove-hook 'jit-lock-functions #'valign-region t)
       (remove-hook 'kill-buffer-hook #'valign--maybe-clean-advice t)
+      (remove-hook 'org-cycle-hook #'valign--org-cycle-re t)
       (valign-reset-buffer)
       (cursor-sensor-mode -1)
       (valign--maybe-clean-advice))))

Diff finished.  Sun Dec 21 14:06:59 2025

Just changed the cond to pcase here. I don't know how to name things, please correct if anything is off.

Tested lightly with

#+title: TEST
#+startup: content

* Integration by Parts

- Formulae Simple:

$\int [u.v] dx = u \int v dx - \int ( \frac{du}{dx} \int v dx ) dx$


- Tabular quick compute

| Sign | Differentiate Variable (u) | Integrate Variable (v) |
|------+----------------------------+------------------------|
| +    | $u$                        | $\int v$                  |
|------+----------------------------+------------------------|
| -    | $du$                       | $\int \int v$                |
|------+----------------------------+------------------------|
| +    | $d^2 u$                    | $\int \int \int v$              |
|------+----------------------------+------------------------|
| -    | $d^3 u$                    | $\int \int \int \int v$            |
|------+----------------------------+------------------------|
| ...  | ...                        | ...                    |

[casouri]

Done. Could you check if the change fixes your issue for me? Thanks.